@echo off

set mypath=%~dp0
set rights_admin=0

:: Check admin rights
NET SESSION >nul 2>&1

IF NOT %ERRORLEVEL% EQU 0 (
   echo ####### Running as a regular user #########
   echo # The Wi-Fi profiles will be installed    #
   echo # for the current user.                   #
   echo # Run as administrator to install them    #
   echo # for all users.                          #
   echo ###########################################
   echo.
   pause
) ELSE (
   set rights_admin=1
)





:: Main loop

:main
cls
ECHO What you want to do now?
ECHO 1. Configure Wi-Fi connection
rem ECHO 2. Configure Wired connection
ECHO 3. Print MAC adresses
ECHO 4. Exit
set choice=
set /p choice=Choice: 
if not '%choice%'=='' set choice=%choice:~0,1%
if '%choice%'=='1' goto setup_wifi
rem if '%choice%'=='2' goto setup_eth
if '%choice%'=='3' goto print_mac
if '%choice%'=='4' EXIT
ECHO "%choice%" is not valid, try again
ECHO.
goto main





:: Import Sincoolka and Sincoolka FT Wi-Fi profile

:setup_wifi
cls
set cmd_user=current
IF %rights_admin% EQU 1 (
   set cmd_user=all
)
netsh wlan add profile "filename=%mypath%Wi-Fi-Sincoolka.xml" user=%cmd_user%
netsh wlan add profile "filename=%mypath%Wi-Fi-SincoolkaFT.xml" user=%cmd_user%

echo.

set /p iface="Press Enter to continue . . . "
goto main





:: Start dot3svc service

:setup_eth
cls
net start dot3svc >nul 2>&1
IF %ERRORLEVEL% EQU 0 (   
  echo Enabled enterprise security for wired connection
) ELSE (
  IF %ERRORLEVEL% EQU 2 (
    echo Enabled enterprise security for wired connection
  ) ELSE (
    echo "Unable to enable enterprise security -> abort"
    goto main
  )
)

:: Configure dot3svc service to start on PC boot
REG add "HKLM\SYSTEM\CurrentControlSet\services\dot3svc" /v Start /t REG_DWORD /d 2 /f >nul 2>&1
IF %ERRORLEVEL% EQU 0 (   
  echo Enterprise security configured to start on PC boot
) ELSE (
  echo Unable to configure enterprise security to start on PC boot -> abort
  goto main
)

echo.
echo.

:setEth
                           
:: Print all network interfaces
echo List of Avaliable Interfaces:
echo.
wmic nic where 'NOT Manufacturer like "%%Microsoft%%" and PhysicalAdapter=TRUE and NOT Manufacturer like "%%Windows%%"' get Manufacturer,MACAddress,NetConnectionID 2>nul
IF NOT %ERRORLEVEL% EQU 0 (
  getmac /v 2>nul
  IF NOT %ERRORLEVEL% EQU 0 (
::  netsh lan show profiles   
    ipconfig /all
  )
)

echo.
set /p iface="Enter Ethernet Interface NetConnectionID or press Enter to abort: "

if "%iface%" == "" (
  goto endEth
)

netsh lan add profile "filename=%mypath%Ethernet.xml" interface="%iface%"

if %errorlevel% GTR 0 (
  set iface=

  cls
  goto setEth
)     
:endEth

goto main





:print_mac
cls
wmic nic where 'NOT Manufacturer like "%%Microsoft%%" and PhysicalAdapter=TRUE and NOT Manufacturer like "%%Windows%%"' get Manufacturer,MACAddress,NetConnectionID 2>nul
IF NOT %ERRORLEVEL% EQU 0 (
  getmac /v 2>nul
  IF NOT %ERRORLEVEL% EQU 0 (
::  netsh lan show profiles   
    ipconfig /all
  )
)
set /p iface="Press Enter to continue . . . "
goto main